/* ROI_Color_Coder.ijm

 This macro colorizes ROIs listed in the Manager by matching ROI measurements to an index of
 a lookup table (LUT). It can be used, e.g., to obtain a particle-size 'heat-map' of segmented
 objects. More info at http://imagejdocu.tudor.lu/doku.php?id=macro:roi_color_coder

 N.B.:
 1) Save this file in the plugins directory and it will be available in the Plugins Menu;
 2) Rename your preferred LUT in the ImageJ/luts directory with a 'rmanager' prefix (e.g.
    'rmanager-Fire.lut') and it will loaded by default;
 3) Check "Edit Mode" in the ROI Manager to toggle particle labeling;
 4) Several 'heat-map' LUTs can be download at <http://rsb.info.nih.gov/ij/download/luts/luts.zip>;
 5) The'glasbey' lookup table <http://rsb.info.nih.gov/ij/download/luts/glasbey.lut> can be used
    to label ROIs randomly

Tiago Ferreira, Dec 2010

2010.12.06 v.4 Added: Accepts all LUT files recognized by ImageJ. Faster
               Fixed: Does not abort when files w/o extension exist in the luts directory
2009.12.14 v.3 Added: Options: transparency, contours width, ROI filling
               Added: Results table is clearead and ROIs (re)measured when needed
2009.12.01 v.2 Fixed: Labels misalignment in legend
*/

// For a demo run the following line:
   // run("Blobs (25K)"); setAutoThreshold; run("Analyze Particles...", "display clear add");

macro "ROI Color Coder" {
    requires("1.44e");
    mCount= roiManager("count"); rCount= nResults; resetRes= true;
    if (nImages==0 || mCount==0)
        verboseExit("Macro aborted: No images open and/or the ROI Manager is empty.");

    msg= ""+ mCount +" ROI(s) in Manager and "+ rCount + " Row(s) in the Results Table";
    if (mCount>rCount)
        msg= msg+":\nPrevious measurements will be cleared and ROIs (re)measured...";
    else if (mCount<rCount)
        msg= msg+":\nThe last "+ rCount-mCount +" row(s) will be ignored";
    else
        resetRes= false;

 // create the dialog prompt
    Dialog.create("ROI Color Coder: "+getTitle);
      parameters= getMeasurements();
      Dialog.addChoice("Colorize ROIs in Manager by:", parameters, "Area");
      luts= getLutList();
      Dialog.addChoice("Using the lookup table:", luts);
      Dialog.addNumber("Contour width (0 to fill ROI):", 3);
      Dialog.addNumber("Opacity (0-100%):",75);
      Dialog.addString("Match last LUT index to:", "max. in measurement column",20);
      getPixelSize(unit, null, null);
      Dialog.addString("Heat-map unit:", unit+"^2");
      Dialog.addMessage(msg);
      Dialog.addHelp("http://imagejdocu.tudor.lu/doku.php?id=macro:roi_color_coder");
    Dialog.show;
        parameter= Dialog.getChoice;
        lut= Dialog.getChoice;
        wdth= Dialog.getNumber;
        alpha= "#"+pad(toHex(255*Dialog.getNumber/100)); // alpha blending: 0, transparent; 255, solid color
        max = Dialog.getString;
        unit= Dialog.getString;

  setBatchMode(true);
    start= getTime;
    max= d2s(max,2);
    if (parameter=="Other...") parameter= getString("Parameter", "");
    if (resetRes) { run("Clear Results"); roiManager('deselect'); roiManager('measure');}

    if (isNaN(max)) {
        values= newArray(nResults);
        for (i=0; i<nResults; i++)
            values[i] = getResult(parameter,i);
        Array.getStatistics(values, min, max);
        if (max==-1/0)
            exit("The Results table does not contain valid data for \""+parameter+"\".");
    }

 // make the heat-map legend
    id= getImageID; saveSettings;
    rampW= 256; rampH= 32; fontS= 14; nTicks= 14; canvasH= fontS+rampW-1; canvasW= rampW/2;
    setBackgroundColor(255,255,255); setColor(0); setLineWidth(1); setFont("Monospaced",fontS);

    newImage(parameter+"-Legend", "32-bit Ramp", rampW, rampH, 1);
    setMetadata("Label", parameter +", "+ lut);

 // load the LUT as a hexColor array
    roiColors= loadLutColors(lut);

 // continue designing the heat map legend
    run("RGB Color");
    drawLine(0, rampH-1, rampW, rampH-1); drawLine(0, 0, rampW, 0); // make vertical scale lines
    run("Rotate 90 Degrees Left");
    run("Canvas Size...", "width="+ canvasW +" height="+ canvasH +" position=Center-Left");
    yPos= fontS/2;    // ramp is now a 31x256 rectangle at (0, 6);
    for (i=0;i<=nTicks;i++) {
        if(i%2)
            l= 4;    // make shorter divison ticks when there are no labels
        else {
            l= 8;    // draw scale ticks and scale values
            drawString(d2s(i*max/nTicks,2), rampH+1, (canvasH+2)-(i*rampW/nTicks)); // 2 pixels shift
        }
        drawLine(rampH-l, canvasH-yPos, rampH-1, canvasH-yPos);
        drawLine(0, canvasH-yPos, l, canvasH-yPos);    // make ticks on both sides of the ramp
        yPos= yPos+(rampW/nTicks);
    }
    unit= replace(unit,"(?<![A-Za-z0-9])u(?=m)",fromCharCode(181)); // find all 'um' not preceded by
    unit= replace(unit,"\\^2",fromCharCode(178));                   // alphanumeric characters and
    unit= replace(unit,"\\^3",fromCharCode(179));                   // all '^2' and '^3' symbols
    uW= minOf(getStringWidth(unit),rampH); spacer= (rampH-uW)/2;
    run("Canvas Size...", "width=&canvasW height="+ canvasH+fontS +" position=Bottom-Left");
    drawString(unit, spacer, fontS);
    restoreSettings;

 // iterate through the ROI Manager list and colorize ROIs
    selectImage(id);
    roiManager("Set Line Width", wdth); countNaN= 0;
    for (i=0; i<mCount; i++) {
        size= getResult(parameter,i);
        if (isNaN(size)) countNaN++;    // just in case the results table has been edited elsewhere
        lutIndex= round((size*255)/max);
        lutIndex= minOf(lutIndex,255);
        roiManager("select", i);
        if (wdth>0)
            roiManager("Set Color", alpha+roiColors[lutIndex]);
        else
            roiManager("Set Fill Color", alpha+roiColors[lutIndex]);
    }
    Overlay.show; // roiManager("Show All");

 // finish
  setBatchMode("exit & display");
    call("java.lang.System.gc");
    showStatus("ROI Color Coder... Finished: "+ d2s((getTime-start)/1000,3) +" seconds");
    if (countNaN!=0) showMessage("Some "+ parameter +" values could not be retrieved.\n"+
                                 countNaN+" ROI(s) labeled with default color.");
}

function getLutList() {
    lutdir = getDirectory("luts");
    if (!File.exists(lutdir))
        verboseExit("Macro aborted: The \"ImageJ/luts/\" directory does not exist.");
    rawlist= getFileList(lutdir);
    count= 0;
    for (i=0; i< rawlist.length; i++)
        if (endsWith(rawlist[i], ".lut")) count++;
    if (count==0)
        verboseExit("Macro aborted: The \"ImageJ/luts/\" directory contains no LUTs.");
    list= newArray(count);
    index= 0; def= -1;
    for (i=0; i< rawlist.length; i++) {
        if (endsWith(rawlist[i], ".lut")) {
                lutnm= substring(rawlist[i], 0, lengthOf(rawlist[i])-4);
                if (startsWith(lutnm, "rmanager")) def= index;
                list[index++]= lutnm;
        }
    }
    if(def!=-1) {   // a "rmanager lut" was found. Make it the 1st item in list
        old1st= list[0]; new1st= list[def];
        list[def]= old1st;
        Array.sort(list);
        list[0]= new1st;
    }
    showStatus("ROI Color Coder: "+ count +" LUT files available");
    return list;
}

function getMeasurements() { // image will be measured. Parameters could just be defined manually
    List.setMeasurements;
    list= split(List.getList, "\n");
    nList= list.length;
    Array.sort(list);
    parameters= newArray(nList+1);
    for (i=0; i<nList; i++)
        parameters[i]= substring(list[i], 0, indexOf(list[i], "="));
    parameters[nList]= "Other...";
    return parameters;
}

function loadLutColors(lut) {
    run(lut); // path= getDirectory("luts")+lut; run("LUT... ", "open=["+ path +"]");
    getLut(reds, greens, blues);
    hexColors= newArray(256);
    for (i=0; i<256; i++) {
        r= toHex(reds[i]); g= toHex(greens[i]); b= toHex(blues[i]);
        hexColors[i]= ""+pad(r)+""+pad(g)+""+pad(b);
    }
    return hexColors;
}

function pad(n) {
    n= toString(n);
    if (lengthOf(n)==1) n= "0"+n;
    return n;
}

function verboseExit(line1) {
    msg= "** "+ line1 +"**\n \n"+
         "ROI Color Coder takes an installed LUT file and uses it to colorize ROIs\n" +
         "in the ROI Manager by matching LUT indexes to measurements in the \n"       +
         "Results table. \n \n"                                                       +
         "It is complementary to the 'Analyze Particles...' command, generating\n"    +
         "particle-size heat maps. For more information see:\n"                       +
         "http://imagejdocu.tudor.lu/doku.php?id=macro:roi_color_coder";
    exit(msg);
}