What is ImageJ's typical performance on various system configurations, and how does my machine compare to them?

ImageJ has a Benchmark utility you can run to evaluate your system's performance.

1. Start up a fresh ImageJ.
2. Choose Plugins > New > Macro from the menu.
3. Paste in the benchmark test macro (from the box below, thanks to Gabriel Landini for providing it).
4. Choose Macros > Run Macro from the menu to execute the benchmark.
5. Compare your results against the table below.

// 512x512 RGB Benchmark Test Macro
//
print("- - - ");
run("Lena (68K)"); // a 512x512 RGB image
id = getImageID;
print("ImageJ: " + getVersion());
print("OS : " + getInfo("os.name") + " " + getInfo("os.version") + 
      " on " + getInfo("os.arch"));
print("Java: "+ getInfo("java.version") + ", vm: " + 
      getInfo("java.vm.version") + " " + getInfo("java.vm.vendor"));
print("JRE: "+ getInfo("sun.boot.library.path"));
 
best = 100000;
worst = -1;
mean = 0;
 
for(i=0; i<10; i++){
   t = getTime();
   run("Benchmark");
   thisrun = getTime()-t;
   mean += thisrun/10;
   if (thisrun<best) best = thisrun;
   if (thisrun>worst) worst = thisrun;
   print("Result "+i+1+": " + d2s(thisrun/1000, 3) + " sec");
}
print("Benchmark best : " + d2s(best/1000, 3) + " seconds");
print("Benchmark mean : " + d2s(mean/1000, 3) + " seconds");
print("Benchmark worst: " + d2s(worst/1000, 3) + " seconds");
 
selectImage(id);
close();